// komuro.inc for POV-Ray Version3.0
// 「POV-Ray入門（小室日出樹著）」収録用のインクルードファイル
// ------------------------------------------------------------------
// Include shapes.ini and colors.ini in advance.
// 必ず shapes.ini と colors.ini をあらかじめインクルードして下さい。
// ------------------------------------------------------------------
// Copyright(c) by Hideki Komuro


#version 3.0

#ifndef (DotKan) #declare DotKan = 2 #end
#ifndef (DotNum) #declare DotNum = 5 #end
#ifndef (DotSize) #declare DotSize = 0.2 #end
#ifndef (AxisRad) #declare AxisRad = 0.1 #end
#ifndef (XVisible) #declare XVisible = on #end
#ifndef (YVisible) #declare YVisible = on #end
#ifndef (ZVisible) #declare ZVisible = on #end


// X,Y,Z軸
#declare XYZaxis =
union{
#if (XVisible)
  object{ Cylinder_X
          texture{ pigment{ color Red } }
          scale AxisRad
  }
#end
#if (YVisible)
object{ Cylinder_Y
        texture{ pigment{ color Blue } }
        scale AxisRad
}
#end
#if (ZVisible)
object{ Cylinder_Z
        texture{ pigment{ color Yellow } }
        scale AxisRad
}
#end

//ドット
#declare AxisDot = object{
  sphere{ <0, 0, 0>, DotSize
    texture{ pigment{ color White } }
  }
}

#declare Cnt = 1
#while ( Cnt <= DotNum )
  #if (XVisible)
    object{ AxisDot
      translate <DotKan*Cnt, 0, 0>
    }
    object{ AxisDot
      translate <-DotKan*Cnt, 0, 0>
    }
  #end
  #if (YVisible)
    object{ AxisDot
      translate <0, DotKan*Cnt, 0>
    }
    object{ AxisDot
      translate <0, -DotKan*Cnt, 0>
    }
  #end
  #if (ZVisible)
    object{ AxisDot
      translate <0, 0, DotKan*Cnt>
    }
    object{ AxisDot
      translate <0, 0, -DotKan*Cnt>
    }
  #end
  #declare Cnt = Cnt + 1
#end
}